# MIT License
#
# Copyright (c) 2026 Andreas Nicolai
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

cmake_minimum_required(VERSION 3.16)
project(ModernQtKugelBad-Example LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_AUTOUIC ON)

# QRhiWidget lives in Qt6::Widgets and is public API since Qt 6.7.
# QRhi itself (rhi/qrhi.h) ships with Qt6::Gui but is only reachable through the
# GuiPrivate target — hence no OpenGL/OpenGLWidgets dependency at all here.
# ShaderTools provides qt_add_shaders(), which runs the qsb shader baker.
find_package(Qt6 6.7 REQUIRED COMPONENTS Core Gui Widgets GuiPrivate ShaderTools)

file( GLOB LIB_SRCS ${PROJECT_SOURCE_DIR}/src/*.cpp )
file( GLOB LIB_HDRS ${PROJECT_SOURCE_DIR}/src/*.h )

add_executable(${PROJECT_NAME}
	${LIB_SRCS}
	${LIB_HDRS}
)

target_include_directories(${PROJECT_NAME} PRIVATE src)

target_link_libraries(${PROJECT_NAME} PRIVATE
	Qt6::Core
	Qt6::Gui
	Qt6::GuiPrivate
	Qt6::Widgets
)

# Compile the Vulkan-flavoured GLSL sources into .qsb shader packs and embed them
# as :/shaders/<name>.qsb. Each pack holds SPIR-V plus the GLSL/HLSL/MSL variants,
# and QRhi picks whichever its active backend needs at pipeline creation time.
# This replaces the shaders.qrc of the OpenGL version, which shipped raw .glsl text.
qt_add_shaders(${PROJECT_NAME} "shaders"
	BATCHABLE
	PRECOMPILE
	OPTIMIZED
	PREFIX "/shaders"
	BASE "${PROJECT_SOURCE_DIR}/shaders"
	GLSL "150,330"
	FILES
		shaders/phong.vert
		shaders/phong.frag
		shaders/instanced.vert
		shaders/grid.vert
		shaders/grid.frag
)
